Parcheggio automatico con Arduino

Questa risorsa è stata scritta dagli studenti dell'Istituto ITIS "Enrico Mattei" di Urbino, della classe 4A/EN, Omiccioli Matteo, Marzi Filippo, Sasha Fasolo Massoli, Daniel Gostoli, Nicolas Mangani e Andrea Piergiovanni nell'a.s. 2021/2022, all'interno del corso di Sistemi automatici per le superiori 2. Per favore, prima di apportare modifiche, attendi sino alla fine dell'anno scolastico (termina il 30 giugno 2022) oppure contatta il docente di riferimento Giacomo Alessandroni nel caso venissero rilevati contenuti non in linea con le linee guida della comunità. Se leggi questo avviso ad anno scolastico concluso puoi rimuoverlo.

Questa risorsa descrive come realizzare un Parcheggio Intelligente, sensorizzato che gestisce automaticamente l'organizzazione dei posti

Presentazione del progetto

Il progetto volge alla realizzazione di un prototipo di parcheggio intelligente. Esso presenta all'esterno un display LCD sul quale viene presentato il numero di posti auto liberi e un visualizzatore luminoso composto da 8 LED RGB, che mostra i posti disponibili e quelli occupati. Al suo interno invece i posteggi sono forniti di sensori a infrarossi che rilevano la presenza dell'auto e la comunicano con il visualizzatore esterno. Per l'ingresso e l'uscita dal parcheggio, vengono utilizzati dei sensori RFID reader, che permettono l'apertura della sbarra (tramite un servomotore), solo con l'apposita chiave elettronica.

Componenti richiesti

Componenti utilizzati

Descrizione	Tipo	Quantità
Arduino	Mega	1
Sensori a infrarossi	TCRT5000	8
LED	RGB	8
Display	LCD 16X2	1
Servomotore	Tower Pro SG90	2
Lettore RFID	RC522	2
RFID tag	ISO14443-A	1

Ingresso e uscita

Lettore RFID

L'accesso e l'uscita dal parcheggio è possibile tramite una chiave magnetica e un lettore RFID.

La chiave (detta anche tag) contiene un codice univoco associato al veicolo che è autorizzato a entrare e uscire. Il tag è un trasponder passivo a radiofrequenza. Funziona come vera e propria chiave elettronica.

La lettura delle chiavi viene eseguita dal lettore RFID: un ricetrasmettitore che legge i dati contenuti nella chiave magnetica e li confronta con l'elenco dei codici autorizzati. L’antenna permette la comunicazione tra il tag e lettore.

In questo caso, avvicinando la chiave magnetica al lettore RFID, se questa contiene un codice autorizzato, si manda un comando al servomotore che alza la sbarra e permette il passaggio dell'autoveicolo, abbassandosi automaticamente dopo il passaggio del veicolo. Questo vale sia per l'ingresso, sia per l'uscita.

Tag RFID

Schema elettrico del circuito di apertura con RFID

Codice

Di seguito il codice che pilota un servomotore quando si accosta una chiave elettronica al lettore RFID.

#include <Servo.h>
#include <SPI.h>
#include <MFRC522.h>

#define SS_PIN 10
#define RST_PIN 9

#define chiave "14 36 E6 E9"

MFRC522 mfrc522(SS_PIN, RST_PIN);
Servo sbarra;
int posizioneSbarra = 180;
int pinSbarra = 7;
int velSbarra = 20; // Velocità con cui si movimenta la sbarra


void setup() {
  Serial.begin(9600);
  Serial.println("Accosta la chiave RFID");
  sbarra.attach(pinSbarra);
  sbarra.write(posizioneSbarra);
  SPI.begin();
  mfrc522.PCD_Init();
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, LOW);
}

void loop() {
  // Non e' presente nessuna carta
  if (!mfrc522.PICC_IsNewCardPresent()){
    return;
  }
  // Non sta leggendo nessuna carta
  if (!mfrc522.PICC_ReadCardSerial()){
    return;
  }
  
  // Lettura chiave elettronica
  String uid = leggiRFID();
  Serial.println(uid);
  // Se la chiave è corretta alza la sbarra
  if(uid.substring(1) == chiave) {
    Serial.println("V");
    mov();
  }
  // Esegue un test ogni 100 ms
  delay(100);
}

// Subroutine di lettura carta
String leggiRFID() {
  String content = "";
  byte letter;
  // Scrive nella porta seriale il codice della chiave
  Serial.print("UID: ");
  for (byte i = 0; i < mfrc522.uid.size; i++){
     content.concat(String(mfrc522.uid.uidByte[i] < 0x10 ? " 0" : " "));
     content.concat(String(mfrc522.uid.uidByte[i], HEX));
  }
  content.toUpperCase();
  return content;
}

// Movimentazione sbarra
void mov() {
  // Alza la sbarra
  delay(3000);
  for (posizioneSbarra = 180; posizioneSbarra >= 90; posizioneSbarra--) {
    sbarra.write(posizioneSbarra);
    delay(velSbarra);
  }
  // Abbassa la sbarra
  delay(5000);
  for (posizioneSbarra = 90; posizioneSbarra <= 180; posizioneSbarra++) {
    sbarra.write(posizioneSbarra);
    delay(velSbarra);
  }  
}

Visualizzatore luminoso di posti liberi

LED RGB con relativa pedinatura

Il progetto prevede l'utilizzo di 8 LED RGB, per comunicare quali – degli otto parcheggi – sono liberi o occupati. Il numero di cavi necessario è pari ai controlli ($8\times 2=16$, relativi ai terminali rossi e verdi) oltre a uno comune per la massa.

Per il visualizzatore è stata realizzata una apposita maschera (stampata con stampante 3D) nella quale sono inseriti gli 8 LED RGB, che – in base al colore rosso o verde – indicano se il posto auto è occupato oppure no.

Espansioni suggerite

Aggiunta di: